桐質問掲示板 [All Thread / Page: 5]

2023/12/23(Sat) 14:27:31 編集(投稿者)

> 昨日から急に、桐10sfor RDS版の一括処理が、固まり先に進めない状況が続いています。
> 止まる場所は、共有更新で開かれている表のある項目を行訂正するところです。
> 自身のローカルに入ってる桐10sでは問題なく動くのですが、毎回、応答なしとなり固まってしまいます。

「餅は餅屋（もちはもちや）」と言いますので、

　意味：餅屋が搗（つ）いた餅は美味いことから、仕事は専門家に任せるの一番であること。

この件はＫ３のカスタマーサポート（ユーザサポート）へ問い合わせるのが一番よいと思いますよ。

ただし、必ず解決するかというと、残念ながらそれはわかりませんが・・・

あいにく週末（土・日）なのでサポートはお休みですが、

早めにメールを送っておくと、週明け早々にサポートが受けられるのではないでしょうか？
・・・・・・・・・・・・

引用返信 [メール受信/OFF]

■記事リスト / レス記事表示 → [親記事-1]

■記事リスト / ▼下のスレッド / ▲上のスレッド

■14080 / 親記事)

　フォーム入力途中でESC

□投稿者/ 篤姫 -(2023/12/21(Thu) 13:01:41)

桐１０S　Windows10

フォームで入力途中にESCで入力を中止した時に
指定のコマンドボタンにフォーカスを移動させたいのですが

よろしくお願いします。

引用返信 [メール受信/OFF]

▽[全レス6件(ResNo.2-6 表示)]

■14082 / ResNo.2)

　Re[1]: フォーム入力途中でESC

□投稿者/ ONnoji -(2023/12/21(Thu) 20:31:27)

2023/12/22(Fri) 14:42:16 編集(投稿者)
2023/12/22(Fri) 10:35:04 編集(投稿者)
2023/12/21(Thu) 21:26:43 編集(投稿者)

> 桐１０S　Windows10
>
> フォームで入力途中にESCで入力を中止した時に
> 指定のコマンドボタンにフォーカスを移動させたいのですが

フォームのテキストボックスにキャレットがある時には、［テキストボックスのエディタ］の中に居ます。

この［テキストボックスのエディタ］とはいわゆる入力用のバッファ（メモリ）の事です。
　　・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・

なので、［テキストボックスのエディタ］に進入している時に発生する［入力後］イベントで他のオブジェクトへフォーカスを移動することは禁止されています。

つまり、［入力後］イベントが終了してから、他のオブジェクトへフォーカスを移動させてちょうだいね、ということです。
　　　　・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・
　◇　◇　◇　◇

私も［実行コマンド：ESCキー］が簡便で面倒くさくないのでお勧めします。
　　・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・

ただし、テキストボックスにキャレットがある時には、ＥＳＣキーを２度押す必要がありますね。

１度めは、［テキストボックスのエディタ］から脱出するために、

そして２度めは、［実行コマンド：ESCキー］の設定のために。

これ位ならば、普通は［この仕様で良し！］じゃないでしょうか？？？？

　◇　◇　◇　◇

それでも、どうしてもというのであればサンプルを添付しますので参考にしてください。

例によってサンプルは数日を目途に削除しますのでダウンロードはお早めに願います。

なお、サンプルでは時限式タイマーを使用しています。

時限式タイマーに関しては拙作ｗｅｂページを参考にしてください。

こちら
　↓
桐の釣魚大全のトップ > フォームアプリケーション教書　第１部
１１　［タイマー］イベントの動的セット
http://silicon7565.html.xdomain.jp/guide/guide_Part1.htm#section11

■ダイアログボックス.WFX

　フォーム
　├ ファミリ
　├ ワークスペース
　│　└ cmdフォーカス移動
　├ フォーム操作バー
　├ フォームヘッダ部
　│　└ tタイトル
　├ フォーム明細部
　│　├ テキスト_8
　│　│　└ ラベル_9
　│　├ テキスト_9
　│　│　└ ラベル_10
　│　└ ラベル_11
　└ フォームフッタ部
　　　├ cmdＯＫ
　　　└ cmdキャンセル

　オブジェクト名： cmdフォーカス移動
　標題　　　　　： cmdフォーカス移動

　　機能名　　　　　機能パラメータリスト
　1 フォーカス移動　 "cmdキャンセル"
　2 なし
　3 なし
　4 なし

■ダイアログボックス.kex

名札　　メイン

＊

手続き定義開始　フォーム::タイマー1()
　変数宣言　自動，文字列｛ &objectName ｝
　変数宣言　自動，整数　｛ &return ｝

　&objectName = "フォーム"
　オブジェクト操作　&objectName｛タイマー1 = 0 ｝　/* 時限式タイマーなので直ちに停止します */

　メソッド呼び出し　戻り値 = &return, @cmdキャンセル.フォーカス設定()
　**戻り値意味
　** 1 フォーカスを移した。
　** 0 フォーカスを移せなかった。
　**-1 フォーカス設定できないハンドラ内で実行した
　トレース出力　_&return

手続き定義終了

手続き定義開始　テキスト_9::入力後(参照　文字列　&編集文字列，長整数　&モード，参照　長整数　&入力継続)
　変数宣言　自動，文字列｛ &objectName ｝
　変数宣言　自動，整数　｛ &interval = 10 ｝　/* 単位は1/100秒ただし、0.1秒以下にはしないこと */
　変数宣言　自動，整数　｛ &return ｝

　トレース出力　&this
　if ( .not &モード )

　　メソッド呼び出し　戻り値 = &return, @cmdキャンセル.フォーカス設定()　/* ＮＧ！です */
　　**戻り値意味
　　** 1 フォーカスを移した。
　　** 0 フォーカスを移せなかった。
　　**-1 フォーカス設定できないハンドラ内で実行した。
　　トレース出力　_&return

　　メソッド呼び出し　戻り値 = &return, @cmdフォーカス移動.実行()　/* ＮＧ！です */
　　トレース出力　_&return
　　**戻り値意味
　　** 1 正常終了。
　　** 1以外実行できない。またはエラーで終了した。

　　**以上のように［入力後］イベントハンドラ実行中にフォーカスを移動することは不可能

　　**次のように、［入力後］イベントハンドラ実行後に時限式タイマーイベントを実行する
　　&objectName = "フォーム"
　　オブジェクト操作　&objectName｛タイマー1 = 1, タイマー値1 = &interval ｝　/* 時限式タイマーをセットします */
　end

手続き定義終了

引用返信 [メール受信/OFF]

■14083 / ResNo.3)

　Re[2]: フォーム入力途中でESC

□投稿者/ 篤姫 -(2023/12/22(Fri) 09:05:49)

通りすがりさん
ありがとうございます。
やってみます。

引用返信 [メール受信/OFF]

■14084 / ResNo.4)

　Re[2]: フォーム入力途中でESC

□投稿者/ 篤姫 -(2023/12/22(Fri) 09:09:00)

ONnojiさん

ご指導いただいたイベント勉強します。

ありがとうございます。

引用返信 [メール受信/OFF]

■14085 / ResNo.5)

　Re[3]: フォーム入力途中でESC

□投稿者/ ONnoji -(2023/12/22(Fri) 11:32:19)

2023/12/22(Fri) 16:54:20 編集(投稿者)

蛇足です。

┌when 手続き"テキスト_9::入力後("2023年12月22日",0,0)"を実行開始しました
│
│　:テキスト_9
│　:&return : -1
│　:&return : 0
│
└end

┌when 手続き"フォーム::タイマー1( )"を実行開始しました
│
│　:&return : 1
│
└end

［入力後］イベントハンドラの引数：&モード/長整数

　入力したデータが確定されたか、キャンセルされたかを示す番号が格納されます。

値説明
1 確定
0 [Esc]キーによるキャンセル

↑これは論理値と同じなので

if ( .not &モード )
　：
end

とすれば、［Esc］キーを検出することになります。

このように便利なのですが、フォーム上にテキストボックスが多数ある時には、

それぞれのオブジェクトごとに［入力後］イベントハンドラを作成しなければなりません。

何故ならば、ファミリには［入力後］イベントハンドラが無いからです。
　　　　　　・・・・・・・・・・・・・・・・・・・・・・
なので、テキストボックスが多数ある時には、コツコツと作るしかありません。(^^ゞ

これは愚直で格好悪く思えますが、一目瞭然なのでヨシだと思います。

　◇　◇　◇　◇　◇　◇　◇　◇　◇　◇　◇

格好悪いのを嫌って、［キーダウン］イベントで対応する方法も考えられますが、

常時［キーダウン］イベントをオンにしておくのは無駄に［キーダウン］イベントが発生するのでデバッグし難いです。
　　　　　　　　　　　　　　　　　　　　　　　・・・・・・・・・・・・・・・・・・・
なので、エディタに進入した時に限り［キーダウン］イベントをオンにして、

それ以外の時には［キーダウン］イベントをオフにするのがスマートです。
　　　　　　　　　　　　　　　　　　　　　　　　　　　・・・・・・
しかし、スマートにしようとすると、今度はプログラムが複雑になります。

なので、［キーダウン］イベントよりも、［入力後］イベントの方が優れていると思いますよ。

なお、［実行コマンド：ESCキー］の方が簡便で面倒臭くないのでお勧めします。

私だったら［Esc］キーを２度押してね！を採用すると思いますよ。

引用返信 [メール受信/OFF]

■14086 / ResNo.6)

　Re[4]: フォーム入力途中でESC

□投稿者/ 篤姫 -(2023/12/22(Fri) 17:08:37)

ONnojiさん
実行コマンドで処理を検討しています。
現在週末で業務処理を行っていますので
時間がある時にやってみます。

ありがとうございます。

引用返信 [メール受信/OFF]

■記事リスト / レス記事表示 → [親記事-6]

■記事リスト / ▼下のスレッド / ▲上のスレッド

■14074 / 親記事)

　（削除）

□投稿者/ -(2023/12/18(Mon) 19:22:51)

この記事は(投稿者)削除されました

引用返信 [メール受信/OFF]

▽[全レス1件(ResNo.1-1 表示)]

■14079 / ResNo.1)

　Re[1]: サブフォームのリンクについて

□投稿者/ 通りすがり -(2023/12/21(Thu) 08:59:27)

ちょっと通りすがったので、質問の意味が取り違えてたり何か勘違いしてるかもだけど
2.tbx と 3.tbx は、一つのテーブルになりませんか？

引用返信 [メール受信/OFF]

■記事リスト / レス記事表示 → [親記事-1]

■記事リスト / ▼下のスレッド / ▲上のスレッド

■14068 / 親記事)

　文字列への入力方法

□投稿者/ 桐太郎 -(2023/12/16(Sat) 10:28:57)

桐10S使用です。
新しく入社した会社で初めて桐を利用しており、勉強中です。
聞くのが恥ずかしいレベルかもしれませんが、
ヘルプや過去掲示板を見てもわからないため教えてください。

2023年12月15日の場合
データ型が数値なら、
(&年-2000)*10000+(&月*100）+&日と入力すると、
231215　になるかと思います。

データ型が文字列の場合、23.12.15　となるようにするには、
どのように入力すればよいか、教えてほしい。

もっとわかりやすいデータの形式にすればというご指摘があるかと思いますが、
新入社員のため、現在の文字列のまま、工夫して入力したく。

引用返信 [メール受信/OFF]

▽[全レス4件(ResNo.1-4 表示)]

■14070 / ResNo.1)

　Re[1]: 文字列への入力方法

□投稿者/ ONnoji -(2023/12/16(Sat) 11:10:42)

2023/12/16(Sat) 11:37:26 編集(投稿者)

> 桐10S使用です。
>
> 2023年12月15日の場合
> データ型が数値なら、
> (&年-2000)*10000+(&月*100）+&日と入力すると、
> 231215　になるかと思います。
>
> データ型が文字列の場合、23.12.15　となるようにするには、
> どのように入力すればよいか、教えてほしい。

数値の231215を、文字列の"23.12.15"に変換するというのであれば、次のように考えると良いですよ。
・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・

１．最初に数値型を文字列型に変換する

２．次に出来上がった６文字の文字列の２文字ずつに切り分ける

３．切り分けた最初の２文字"23"に点（.）を連結して、
　　２番めの文字列の２文字"12"に点（.）を連結して、
　　　最後の２文字の文字列"15"を連結する

具体的には、

１．は、#str( 231215 ) ←これで文字列型に変換されます

２．は、最初の２文字が、#sstr( "231215", 1, 2 )
　　　　次のの２文字が、#sstr( "231215", 3, 2 )
　　　　最後の２文字が、#sstr( "231215", 5, 2 )

３．は、#sstr( "231215", 1, 2 ) + "." + #sstr( "231215", 3, 2 ) + "." + #sstr( "231215", 5, 2 )

　　　　※桐の文字列連結演算子は＋記号です　ご注意：＆記号ではありません

さらに具体的には、表の［数値yymmdd］という項目に６桁の数値値が格納されている場合を例にしますと、

#sstr( #str( [数値yymmdd] ), 1, 2 ) + "." + #sstr( #str( [数値yymmdd] ), 3, 2 ) + "." + #sstr( #str( [数値yymmdd] ), 5, 2 )

という具合です。

なお、関数名の #str　は #文字列と同じです　※使い方はヘルプを見てね
　　　関数名の #sstr は #部分列と同じです　※使い方はヘルプを見てね

引用返信 [メール受信/OFF]

■14071 / ResNo.2)

　Re[2]: 文字列への入力方法

□投稿者/ 桐太郎 -(2023/12/16(Sat) 14:05:16)

2023/12/16(Sat) 14:06:01 編集(投稿者)
2023/12/16(Sat) 14:05:58 編集(投稿者)

解決しました。早速のご回答、ありがとうございました。

わかりづらい説明で申し訳なかったですが、
数値の項目が格納されているわけではなかったので、
以下としました。

#str(&年-2000)+ "." +#str(&月)+ "." +#str(&日)

解決済み!

引用返信 [メール受信/OFF]

■14072 / ResNo.3)

　Re[3]: 文字列への入力方法

□投稿者/ ONnoji -(2023/12/16(Sat) 15:42:19)

> 数値の項目が格納されているわけではなかったので、
> 以下としました。
>
> #str(&年-2000)+ "." +#str(&月)+ "." +#str(&日)

これだと月が１～９、日が１～９の時にちょっと困るでしょうか？？

例えば、２０２４年１月１日だとすると、"24.1.1" になっちゃいますよ。

なので、

×　#str(&年-2000)+ "." +#str(&月)+ "." +#str(&日)

〇　#str(&年-2000)+ "." +#str(&月, 2 )+ "." +#str(&日, 2 )

関数名の #str　は #文字列と同じです　※使い方はヘルプを見てね

引用返信 [メール受信/OFF]

■14073 / ResNo.4)

　Re[4]: 文字列への入力方法

□投稿者/ 桐太郎 -(2023/12/16(Sat) 17:47:12)

> これだと月が１～９、日が１～９の時にちょっと困るでしょうか？？
>
> 例えば、２０２４年１月１日だとすると、"24.1.1" になっちゃいますよ。
>

ご指摘のとおり、困ります。
1月になるまで気づかなかったと思います。
大変助かりました。
ありがとうございました。

解決済み!

引用返信 [メール受信/OFF]

■記事リスト / レス記事表示 → [親記事-4]

■記事リスト / ▲上のスレッド

■14066 / 親記事)

　毎月２日から翌月１日までを１ヶ月（２日の日の属する月）とする行集計の方法について

□投稿者/ T.S -(2023/12/15(Fri) 21:47:44)

Ｔ.Ｓと申します。
いつもお世話になっております。
桐Ｖ９-2012　です。

　従業員の勤務実績管理表（[氏名]、[ymd_数値]、[実績時間数]）を作成し、毎月々従業員ごとの勤務時間を３ヶ月単位で集計しています。

●_困りごと

　年月日を数値で持っている項目[ymd_数値]で、毎月２日から翌月１日までを１ヶ月分として時間型で持っている項目[実績時間数]を集計する場合、

毎月２日から翌月１日までを集計単位（集計グループ）として、行集計の集計グループ等をどのようにしたら良いか、良いお知恵をご教示いただければと思います。

（現在は、桐左端数字の行を毎月２日から翌月１日までの行を手でドラックして、右クリック－絞り込み－選択行　を人ごとに、ひと月ひと月行い、行集計をしています。）

　よろしくお願いします。

TBLイメージ

[氏名]、[ymd_数値]、[実績時間数]
東京　太郎、20230830、7時間45分
東京　太郎、20230831、1時間00分
東京　太郎、20230901、2時間10分
東京　太郎、20230902、3時間15分
東京　太郎、20230903、4時間20分
東京　太郎、20230904、5時間25分
・・・
東京　太郎、20230928、6時間45分
東京　太郎、20230929、7時間50分
東京　太郎、20230930、8時間35分
東京　太郎、20231001、7時間25分
東京　太郎、20231002、6時間15分
東京　太郎、20231003、5時間05分
東京　太郎、20231004、4時間45分

●_作業　20230902から20231001までの実績時間数を９月分として行集計(#合計)したい。

引用返信 [メール受信/OFF]

▽[全レス2件(ResNo.1-2 表示)]

■14067 / ResNo.1)

　Re[1]: 毎月２日から翌月１日までを１ヶ月（２日の日の属する月）とする行集計の方法について

□投稿者/ ONnoji -(2023/12/15(Fri) 23:05:17)

> 桐Ｖ９-2012　です。
>
> 毎月２日から翌月１日までを集計単位（集計グループ）として、
> 行集計の集計グループ等をどのようにしたら良いか、良いお知恵をご教示いただければと思います。
>
> ●_作業　20230902から20231001までの実績時間数を９月分として行集計(#合計)したい。

単純に[ymd_数値]の値を２日分差し引いて、年と月の６桁に整形するでイケるかと思いますが・・・

具体的には、

新しくグループとしての項目を１つ用意して

数値型ならば

　#num( #sstr( #str( [ymd_数値] - 2 ), 1, 6 ) )

文字列型ならば

　#sstr( #str( [ymd_数値] - 2 ), 1, 6 )

という項目計算式を設定してもよいし、または集計する直前に式で置換してもＯＫです。

引用返信 [メール受信/OFF]

■14069 / ResNo.2)

　Re[2]: 毎月２日から翌月１日までを１ヶ月（２日の日の属する月）とする行集計の方法について

□投稿者/ T.S -(2023/12/16(Sat) 10:44:58)

ONnoji　様　回答いただきありがとうございます。

> 単純に[ymd_数値]の値を２日分差し引いて、年と月の６桁に整形するでイケるかと思いますが・・・

　なるほど、そう考えればよっかたのですね。勉強になります。

> 新しくグループとしての項目を１つ用意して
> 数値型ならば
> 　#num( #sstr( #str( [ymd_数値] - 2 ), 1, 6 ) )
> 文字列型ならば
> 　#sstr( #str( [ymd_数値] - 2 ), 1, 6 )
> という項目計算式を設定してもよいし、または集計する直前に式で置換してもＯＫです。

　数値型でデータを持っていますので、新たな項目を作成後、項目計算式を設定したいと思います。

　大変助かりました。

　どうも有難うございました。

解決済み!

引用返信 [メール受信/OFF]

■記事リスト / レス記事表示 → [親記事-2]

＜前のスレッド5件 | 次のスレッド5件＞

- Child Tree -
- Antispam Version -