桐質問掲示板 [One Topic All View / クリックスライド入力 / Page: 0]

[ 最新記事及び返信フォームをトピックトップへ ]

■13836 / inTopicNo.1)

　クリックスライド入力

□投稿者/ 尾形 -(2023/07/06(Thu) 05:44:50)

よろしくお願いします
桐10sです
上手く伝わるか心配ですが

クリックしてから、そのまま横にスライドして
時間を入力したいと思っています

[作業] [開始] [終了]　1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 以下
作業A　8:00　12:00　　　　　　　　 * * *　*　*
作業B　14:00 15:00　　　　　　　　　　　　　　　　　 *　*

画面的にはこんなイメージです
8欄をクリックしてそのままマウスを12欄まで右にスライドしたら
[開始] と [終了] に時間が入る

こんな操作性を実現したいのですが
桐で可能なものでしょうか

参考になりそうなサンプルありませんでしょうか

よろしくお願いします

引用返信 [メール受信/OFF] 削除キー/

■13837 / inTopicNo.2)

　Re[1]: クリックスライド入力

▲▼■

□投稿者/ 篤姫 -(2023/07/06(Thu) 09:07:15)

桐ver9のサンプルで
会議室予約ってのがあるのですが
ご確認ください。

引用返信 [メール受信/OFF] 削除キー/

■13838 / inTopicNo.3)

　Re[2]: クリックスライド入力

▲▼■

□投稿者/ 尾形 -(2023/07/06(Thu) 10:45:12)

知りませんでした
勉強してみます

とてもうれしいです
ありがとうございました

解決済み!

引用返信 [メール受信/OFF] 削除キー/

■13839 / inTopicNo.4)

　Re[1]: クリックスライド入力

▲▼■

□投稿者/ ONnoji -(2023/07/06(Thu) 11:45:07)

2023/07/06(Thu) 15:23:51 編集(投稿者)
2023/07/06(Thu) 13:43:52 編集(投稿者)

> クリックしてから、そのまま横にスライドして
> 時間を入力したいと思っています
>
>
> [作業] [開始] [終了]　1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 以下
> 作業A　8:00　12:00　　　　　　　　　* * *　*　*
> 作業B　14:00 15:00　　　　　　　　　　　　　　　　　 *　*
>
> 画面的にはこんなイメージです

典型的なマウスドラッグ操作だと思いますが、桐のサンプルは余計な部分がたくさんあるので、シンプルな内容の方がよろしいかと思います。

すでに、速攻で解決済みですが、簡単なサンプルを作りましたのでご紹介します。

なお、サンプルは数時間を目途に削除しますので、ダウンロードはお早めに願います。

また、フォームとイベントは桐9-2012で作成してありますので、桐１０ｓでご利用される場合には桐コンバータで変換してください。

なお、イベント名は半角のカナでも桐１０ｓで動作するので書き換えは不要です。

ｐ．ｓ．

なお、サンプルは余計なことは一切していませんので実際に即応用というのは難しいかもしれません。
しかし、動作の仕組みは実にシンプルなのでご理解いただきやすいと思います。

> クリックしてから、そのまま横にスライドして

クリックした場合には横にスライドしてもドラッグになりません。
・・・・・・・・・・・・・・・・・・・・・・・・・・・・・
必ず、マウス左ダウン、つまりマウス左ボタンを押したまま離さないでスライドしてください。
・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・

　◇　◇　◇　◇　◇　◇　◇　◇　◇　◇　◇　◇　◇　◇　◇　◇

＜参考＞

■ドラッグで時間を.wfm　NULLフォーム

　ﾌｫｰﾑ
　├ ﾌｧﾐﾘ
　│　└ famTxt
　├ ﾜｰｸｽﾍﾟｰｽ
　├ ﾌｫｰﾑﾍｯﾀﾞ部
　├ ﾌｫｰﾑ明細部
　│　├ txt00 ─┐
　│　├ txt01 　│
　│　├ txt02 　│
　│　├ txt03 　│
　│　├ txt04 　│
　│　├ txt05 　│
　│　├ txt06 　│
　│　├ txt07
　│　├ txt08 （重要）
　│　├ txt09　txt00 ～ txt23 のテキストオブジェクトは
　│　├ txt10　ファミリ：famTxt に所属しています
　│　├ txt11
　│　├ txt12 　│
　│　├ txt13 　│
　│　├ txt14 　│
　│　├ txt15 　│
　│　├ txt16 　│
　│　├ txt17 　│
　│　├ txt18 　│
　│　├ txt19 　│
　│　├ txt20 　│
　│　├ txt21 　│
　│　├ txt22 　│
　│　├ txt23 ─┘
　│　└ cmdリセット
　└ ﾌｫｰﾑﾌｯﾀ部
　　　└ cmd閉じる

■ドラッグで時間を.kev

名札　　メイン
　変数宣言　局所，文字列｛ &mFormObjectName, &workString ｝
　変数宣言　局所，文字列｛ &mFamObjectName ｝
　変数宣言　局所，整数　｛ &mOnMouseDown ｝

　メソッド呼び出し　オブジェクト取得( 0，&workString )
　メソッド呼び出し　&workString．親オブジェクト取得( &mFormObjectName )

　&mFamObjectName = "famTxt"

　手続き実行　cmdリセットClick( )
＊

手続き定義開始　famTxt::ﾏｳｽｲﾝｱｳﾄ(長整数　&フラグ，長整数　&明細番号)

　トレース出力　&this, "　 ", _&フラグ, "　 ", #cond( &フラグ, "in", 1, "out" ), "　ﾏｳｽｲﾝｱｳﾄ"

　if ( &フラグ )

　　オブジェクト操作　&this｛背景色 = "水色" ｝

　end

手続き定義終了

手続き定義開始　famTxt::ﾏｳｽ左ﾀﾞｳﾝ(長整数　&マウス位置[2]，長整数　&明細番号，長整数　&フラグ，参照　長整数　&処理中止)

　トレース出力　&this, "　 ", _&フラグ, "　ﾏｳｽ左ﾀﾞｳﾝ"
　オブジェクト操作　&mFamObjectName｛ﾏｳｽｲﾝｱｳﾄ　= 1 ｝
　オブジェクト操作　&mFamObjectName｛ﾏｳｽ左ｱｯﾌﾟ = 1 ｝
　&mOnMouseDown = 1
　オブジェクト操作　&this｛背景色 = "水色" ｝

手続き定義終了

手続き定義開始　famTxt::ﾏｳｽ左ｱｯﾌﾟ(長整数　&マウス位置[2]，長整数　&明細番号，長整数　&フラグ)

　トレース出力　&this, "　 ", _&フラグ, "　ﾏｳｽ左ｱｯﾌﾟ"
　オブジェクト操作　&mFamObjectName｛ﾏｳｽｲﾝｱｳﾄ　= 0 ｝
　オブジェクト操作　&mFamObjectName｛ﾏｳｽ左ｱｯﾌﾟ = 0 ｝
　&mOnMouseDown = 0

手続き定義終了

手続き定義開始　cmdリセットClick( )
　変数宣言　自動，文字列｛ &objectName ｝
　変数宣言　自動，整数　｛ &i, &loop, &step = 1 ｝

　** txt00 ～ txt23
　&loop = 23
　繰り返し　&i = 0, &loop, &step

　　&objectName = "txt" + #str( &i, 2 )
　　**トレース出力　&i, "　 ", _&objectName

　　オブジェクト操作　&objectName｛背景色 = "白" ｝
　繰り返し終了

　手続き実行　prcマウスイベント初期化( )

手続き定義終了

手続き定義開始　prcマウスイベント初期化( )

　オブジェクト操作　&mFamObjectName｛ﾏｳｽｲﾝｱｳﾄ　= 0 ｝
　オブジェクト操作　&mFamObjectName｛ﾏｳｽ左ﾀﾞｳﾝ = 1 ｝
　&mOnMouseDown = 0

手続き定義終了

＜蛇足＞

>> [作業] [開始] [終了]　1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 以下
>> 作業A　8:00　12:00　　　　　　　　　* * *　*　*
>> 作業B　14:00 15:00　　　　　　　　　　　　　　　　　 *　*
>>
>> 画面的にはこんなイメージです

これは作業工程のタイムテーブルなんでしょうかねぇ～？？？
カード形式のフォームで、（会議室予約のような）複数のタイムテーブルを表示して編集するのは面倒そうです。
・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・
一覧表形式のフォームでの明細行で、タイムテーブルを表示して編集するのはさらに面倒そうです。
・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・
やはり、カード形式のフォームで、ひとつのタイムテーブルを表示して編集するのが良さそうですね。
そして、一覧表形式のフォームの明細行の入力支援ボタンから、そのカード形式のフォームを呼び出すのがシンプルですね。

引用返信 [メール受信/OFF] 削除キー/

■13840 / inTopicNo.5)

　Re[2]: クリックスライド入力

▲▼■

□投稿者/ 尾形 -(2023/07/06(Thu) 13:37:25)

ONnojiさん
ありがとうございます

併せて勉強させていただきます

引用返信 [メール受信/OFF] 削除キー/

■13841 / inTopicNo.6)

　Re[2]: クリックスライド入力

▲▼■

□投稿者/ 尾形 -(2023/07/06(Thu) 17:26:53)

どうも、ありがとうございます

> 一覧表形式のフォームでの明細行で、タイムテーブルを表示して編集するのは

そうなんです
サンプル見ていて気になりました

作業は追加可能にしますので
一覧表形式になると思います

> 一覧表形式のフォームの明細行の入力支援ボタンから、
> そのカード形式のフォームを呼び出すのがシンプルですね。

多分これでは入力者は入力してくれないです

引用返信 [メール受信/OFF] 削除キー/

■13842 / inTopicNo.7)

　Re[3]: クリックスライド入力

▲▼■

□投稿者/ ONnoji -(2023/07/06(Thu) 18:23:55)

2023/07/06(Thu) 19:53:47 編集(投稿者)
2023/07/06(Thu) 19:02:29 編集(投稿者)
2023/07/06(Thu) 18:34:20 編集(投稿者)

>>一覧表形式のフォームの明細行の入力支援ボタンから、
>>そのカード形式のフォームを呼び出すのがシンプルですね。
>
> 多分これでは入力者は入力してくれないです

一覧表形式のフォームの明細行で、［マウスドラッグのイベント］を組むのは・・・
私の直感では難しいと感じます。
なぜならば、明細行の領域は［繰り返し表示］されているので、
どの行のオブジェクトで発生したイベントなのかを考慮する必要があるからです。
・・・・・・・・・・・・・・・・・・・・・・
というわけで、私( ONnoji )は今まで明細行での［マウスドラッグのイベント］は避けています。
つまり、経験ゼロでまったく知見を有していませんので悪しからず。(^^ゞ

代替案としては、ヘッダ部またはフッタ部に明細データを表示して、
［マウスドラッグのイベント］を組むというのが考えられそうです。
ヘッダ部またはフッタ部に表示している明細データは［繰り返し表示］されているわけではないので扱いがシンプルです。

以上、全部タラレバですけど・・・(^^ゞ

ｐ．ｓ．

> どの行のオブジェクトで発生したイベントなのかを考慮する必要があるからです。

これは杞憂かもしれないですね。
なぜならば、別の行のオブジェクトをマウス左ダウンすれば、行が替わってしまいますからね。
トライしてみる価値はあると思いますよ。
・・・・・・・・・・・・・・・・・・

と応援しておきながら、(^^ゞ
私（ ONnoji ）はマトリクス（格子）の空欄記入方式では難しいことはやらない主義です。
なぜならば、デバッグが大変だからです。
ちなみに、利用者側は表計算ソフトに慣れているので、似たようなインターフェースを求めるものですがね。
困ったものです。アハハハha

ｐ．ｐ．ｓ．

>>一覧表形式のフォームの明細行の入力支援ボタンから、
>>そのカード形式のフォームを呼び出すのがシンプルですね。
>
> 多分これでは入力者は入力してくれないです

[入力支援ボタン]オブジェクトの［自動表示］を"未定義時"にしておけば、
モーダルフォームが自動で開くので、
オペレータが[入力支援ボタン]オブジェクトをクリックする手間を省けますよ。
フォームの編集モードも気にしなくていいですからねぇ～。
・・・・・・・・・・・・・・・・・・・・・・・・・・
これがシンプルでデバッグがやり易いのでおススメなんですがね。アハハha
・・・・・・・・・・・・・・・・・・・・・・・・・・・・・

引用返信 [メール受信/OFF] 削除キー/

■13844 / inTopicNo.8)

　Re[3]: クリックスライド入力

▲▼■

□投稿者/ ONnoji -(2023/07/07(Fri) 10:04:32)

2023/07/07(Fri) 20:34:21 編集(投稿者)
2023/07/07(Fri) 13:02:14 編集(投稿者)

拙速で作成したサンプルだったので、気に入らないところがありました。
フォームをそのまま変更せず、イベント処理だけをちょっとだけ改訂しました。

■ドラッグで時間を.kev

＜プロシージャの一覧＞

名札　　メイン
└ cmdリセットClick
　　├ prc背景色初期化
　　└ prcマウスイベント初期化

famTxt::ﾏｳｽｲﾝｱｳﾄ

famTxt::ﾏｳｽ左ﾀﾞｳﾝ
└ prc背景色初期化

famTxt::ﾏｳｽ左ｱｯﾌﾟ

cmdリセットClick
├ prc背景色初期化
└ prcマウスイベント初期化

prcマウスイベント初期化

prc背景色初期化

＜イベント処理の内容＞　※コピペで利用できます

名札　　メイン
　変数宣言　局所，文字列｛ &mFormObjectName, &workString ｝
　変数宣言　局所，文字列｛ &mFamilyObjectName ｝
　変数宣言　局所，整数　｛ &mOnMouseDownMode ｝

　メソッド呼び出し　オブジェクト取得( 0，&workString )
　メソッド呼び出し　&workString．親オブジェクト取得( &mFormObjectName )

　&mFamilyObjectName = "famTxt"

　手続き実行　cmdリセットClick( )
＊

手続き定義開始　famTxt::ﾏｳｽｲﾝｱｳﾄ(長整数　&フラグ，長整数　&明細番号)

　トレース出力　&this, "　 ", _&フラグ, "　 ", #cond( &フラグ, "in", 1, "out" ), "　ﾏｳｽｲﾝｱｳﾄ"

　if ( &フラグ )

　　オブジェクト操作　&this｛背景色 = "水色" ｝

　end

手続き定義終了

手続き定義開始　famTxt::ﾏｳｽ左ﾀﾞｳﾝ(長整数　&マウス位置[2]，長整数　&明細番号，長整数　&フラグ，参照　長整数　&処理中止)

　トレース出力　&this, "　 ", _&フラグ, "　ﾏｳｽ左ﾀﾞｳﾝ"
　オブジェクト操作　&mFamilyObjectName｛ﾏｳｽｲﾝｱｳﾄ　= 1 ｝
　オブジェクト操作　&mFamilyObjectName｛ﾏｳｽ左ｱｯﾌﾟ = 1 ｝
　&mOnMouseDownMode = 1

　手続き実行　prc背景色初期化( )
　オブジェクト操作　&this｛背景色 = "水色" ｝

手続き定義終了

手続き定義開始　famTxt::ﾏｳｽ左ｱｯﾌﾟ(長整数　&マウス位置[2]，長整数　&明細番号，長整数　&フラグ)

　トレース出力　&this, "　 ", _&フラグ, "　ﾏｳｽ左ｱｯﾌﾟ"
　オブジェクト操作　&mFamilyObjectName｛ﾏｳｽｲﾝｱｳﾄ　= 0 ｝
　オブジェクト操作　&mFamilyObjectName｛ﾏｳｽ左ｱｯﾌﾟ = 0 ｝
　&mOnMouseDownMode = 0

手続き定義終了

手続き定義開始　cmdリセットClick( )

　手続き実行　prc背景色初期化( )
　手続き実行　prcマウスイベント初期化( )

手続き定義終了

手続き定義開始　prcマウスイベント初期化( )

　オブジェクト操作　&mFamilyObjectName｛ﾏｳｽｲﾝｱｳﾄ　= 0 ｝
　オブジェクト操作　&mFamilyObjectName｛ﾏｳｽ左ﾀﾞｳﾝ = 1 ｝
　&mOnMouseDownMode = 0

手続き定義終了

手続き定義開始　prc背景色初期化( )
　変数宣言　自動，文字列｛ &objectName ｝
　変数宣言　自動，整数　｛ &i, &loop, &step = 1 ｝

　** txt00 ～ txt23
　&loop = 23
　繰り返し　&i = 0, &loop, &step

　　&objectName = "txt" + #str( &i, 2 )
　　**トレース出力　&i, "　 ", _&objectName

　　オブジェクト操作　&objectName｛背景色 = "白" ｝
　繰り返し終了

手続き定義終了

ｐ．ｓ．

なお、当サンプルは［オブジェクトの背景色］の色付けを［マウス左ダウン］と［マウスインアウト］のインの時に行っています。
これは簡便な方法です。
ちゃんと行うには［マウス移動］を使いマウスの位置を読み取って、左右に移動した分に相当する範囲の色付けが必要です。
しかし、こうすると急に複雑になるので当サンプルでは採用していません。

これは、マウスドラッグ（またはドラッグ＆ドロップ）のキモを知っていただきたいという趣旨からの簡便方法です。
・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・
重要な点は、［マウス左ダウン］イベントでドラッグが始まり、［マウス左アップ］イベントでドラッグが終わるということです。
・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・
この始まりと終わりの区間で、必要とされるイベントを動的にオン／オフするというのがお決まり事です。
・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・
と、まあ本格的にやろうとすると大変なのでありました。(^^ゞ

ちなみに、ドラッグ＆ドロップの例の解説は以下の拙作ｗｅｂページに掲載しています。
こちら
　↓
桐の釣魚大全のトップ > フォームアプリケーション教書　第１部
１６．５　マウス左ダウン／マウス移動／マウス左アップで［ドラッグ＆ドロップ］
http://silicon7565.html.xdomain.jp/guide/guide_Part1.htm#section16-5

引用返信 [メール受信/OFF] 削除キー/

■13848 / inTopicNo.9)

　Re[1]: クリックスライド入力

▲▼■

□投稿者/ ONnoji -(2023/07/08(Sat) 16:48:18)

2023/08/11(Fri) 00:03:09 編集(投稿者)
2023/08/08(Tue) 17:47:57 編集(投稿者)
2023/07/09(Sun) 11:02:11 編集(投稿者)

※記事とサンプルを差し替えました。

一覧表形式のフォームのサンプルをアップしました。

［内容］項目にキャレットがある時に 00～23 の項目をマウスドラッグすると、アスタリスク( ＊ )記号に置き換えます。

これはプロトタイプですのでドラッグ機能だけです。(^^ゞ

なお、添付ファイルは数日を目途に削除しますので、ダウンロードはお早めに願います。

　◇　◇　◇　◇　◇　◇　◇　◇

■時間割一覧.tbl

番号　項目名　　データ型
　 1　内容　　　文字列
　 2　00h 　　　　文字列
　 3　01h 　　　　文字列
　 4　02h 　　　　文字列
　 5　03h 　　　　文字列
　 6　04h 　　　　文字列
　 7　05h 　　　　文字列
　 8　06h 　　　　文字列
　 9　07h 　　　　文字列
　10　08h 　　　　文字列
　11　09h 　　　　文字列
　12　10h 　　　　文字列
　13　11h 　　　　文字列
　14　12h 　　　　文字列
　15　13h 　　　　文字列
　16　14h 　　　　文字列
　17　15h 　　　　文字列
　18　16h 　　　　文字列
　19　17h 　　　　文字列
　20　18h 　　　　文字列
　21　19h 　　　　文字列
　22　20h 　　　　文字列
　23　21h 　　　　文字列
　24　22h 　　　　文字列
　25　23h 　　　　文字列
　26　編集フラグ　整数

■時間割一覧.wfm

　ﾌｫｰﾑ
　├ ﾌｧﾐﾘ
　│　└ famTxt
　├ ﾜｰｸｽﾍﾟｰｽ
　├ ﾌｫｰﾑ操作ﾊﾞｰ
　├ ﾌｫｰﾑﾍｯﾀﾞ部
　│　├ lbl内容
　│　├ lbl00
　│　├ lbl01
　│　├ lbl02
　│　├ lbl03
　│　├ lbl04
　│　├ lbl05
　│　├ lbl06
　│　├ lbl07
　│　├ lbl08
　│　├ lbl09
　│　├ lbl10
　│　├ lbl11
　│　├ lbl12
　│　├ lbl13
　│　├ lbl14
　│　├ lbl15
　│　├ lbl16
　│　├ lbl17
　│　├ lbl18
　│　├ lbl19
　│　├ lbl20
　│　├ lbl21
　│　├ lbl22
　│　├ lbl23
　│　├ txtシグナル　※ｿｰｽ = #cond( #変数( "mOnMouseDownMode" ), "Ready" )
　│　└ lbl操作説明
　└ ﾌｫｰﾑ明細部
　　　├ 行ｾﾚｸﾀ
　　　├ txt内容　※編集属性式：#cond( [編集フラグ], "背景ﾓｰﾄﾞ'指定色',背景色'若草色'" )
　　　├ txt00 ─┐
　　　├ txt01 　│
　　　├ txt02 　│
　　　├ txt03 　│
　　　├ txt04 　│
　　　├ txt05 　│
　　　├ txt06 　│
　　　├ txt07
　　　├ txt08 （重要）
　　　├ txt09　txt00 ～ txt23 のテキストオブジェクトは
　　　├ txt10　ファミリ：famTxt に所属しています
　　　├ txt11
　　　├ txt12　＜2023.08.08　追記＞
　　　├ txt13　ﾌｫｰｶｽの設定 = 禁止に設定されています
　　　├ txt14　これはマウス左ダウンした際にテキストオブジェクトのエディタに進入しないようにするためです
　　　├ txt15
　　　├ txt16 　│
　　　├ txt17 　│
　　　├ txt18 　│
　　　├ txt19 　│
　　　├ txt20 　│
　　　├ txt21 　│
　　　├ txt22 　│
　　　└ txt23 ─┘

■時間割一覧.kev

名札　　メイン
　変数宣言　局所，文字列｛ &mFormObjectName, &workString ｝
　変数宣言　局所，文字列｛ &mFamilyObjectName ｝
　変数宣言　局所，整数　｛ &mFormEditMode ｝
　変数宣言　局所，整数　｛ &mOnMouseDownMode ｝
　変数宣言　局所，整数　｛ &mDetailLineNo ｝

　メソッド呼び出し　オブジェクト取得( 0，&workString )
　メソッド呼び出し　&workString．親オブジェクト取得( &mFormObjectName )

　&mFamilyObjectName = "famTxt"
　手続き実行　prcマウスイベント初期化( )

＊

手続き定義開始　famTxt::ﾏｳｽｲﾝｱｳﾄ(長整数　&フラグ，長整数　&明細番号)
　変数宣言　自動，文字列｛ &fieldName ｝

　トレース出力　&this, "　 ", _&フラグ, "　 ", #cond( &フラグ, "in", 1, "out" ), "　ﾏｳｽｲﾝｱｳﾄ"

　if ( &フラグ )

　　&fieldName = #文字置換( &this, "txt", #u ) + "h"
　　トレース出力　&this, " → " + &fieldName, "　ﾏｳｽｲﾝｱｳﾄ"
　　項目値代入　 &fieldName = "＊"

　end

手続き定義終了

手続き定義開始　famTxt::ﾏｳｽ左ﾀﾞｳﾝ(長整数　&マウス位置[2]，長整数　&明細番号，長整数　&フラグ，参照　長整数　&処理中止)
　変数宣言　自動，文字列｛ &fieldName ｝

　メソッド呼び出し　&mFormObjectName.更新モード取得( &mFormEditMode )
　トレース出力　_&mFormEditMode, "　ﾏｳｽ左ﾀﾞｳﾝ", "　 ", _&明細番号, "　 ", _&mDetailLineNo

　if ( &mFormEditMode )　/* 表示モードではマウスドラッグのモード（ &mOnMouseDownMode ）に入らない */

　　if ( &明細番号 = &mDetailLineNo )
　　　オブジェクト操作　&mFamilyObjectName｛ﾏｳｽｲﾝｱｳﾄ　= 1 ｝
　　　オブジェクト操作　&mFamilyObjectName｛ﾏｳｽ左ｱｯﾌﾟ = 1 ｝
　　　&mOnMouseDownMode = 1
　　　メソッド呼び出し　&mFormObjectName.変数変更( )

　　　手続き実行　prc項目値クリア( )

　　　&fieldName = #文字置換( &this, "txt", #u ) + "h"
　　　トレース出力　&this, " → " + &fieldName, "　ﾏｳｽ左ﾀﾞｳﾝ"
　　　項目値代入　 &fieldName = "＊"
　　end

　end

手続き定義終了

手続き定義開始　famTxt::ﾏｳｽ左ｱｯﾌﾟ(長整数　&マウス位置[2]，長整数　&明細番号，長整数　&フラグ)

　トレース出力　&this, "　 ", _&フラグ, "　ﾏｳｽ左ｱｯﾌﾟ"
　オブジェクト操作　&mFamilyObjectName｛ﾏｳｽｲﾝｱｳﾄ　= 0 ｝
　オブジェクト操作　&mFamilyObjectName｛ﾏｳｽ左ｱｯﾌﾟ = 0 ｝
　&mOnMouseDownMode = 0
　メソッド呼び出し　&mFormObjectName.変数変更( )

手続き定義終了

手続き定義開始　txt内容::入力前(参照　文字列　&編集文字列)

　メソッド呼び出し　&mFormObjectName.明細番号取得( &mDetailLineNo )
　トレース出力　&this, "　 ", _&mDetailLineNo, "　入力前"

　メソッド呼び出し　&mFormObjectName.更新モード取得( &mFormEditMode )
　トレース出力　&this, "　 ", _&mFormEditMode, "　 ", _#eof, "　入力前"

　if ( .not #eof )
　　項目値代入　 [編集フラグ] = 1
　end

手続き定義終了

手続き定義開始　txt内容::入力後(参照　文字列　&編集文字列，長整数　&モード，参照　長整数　&入力継続)

　&mDetailLineNo = #u
　トレース出力　&this, "　 ", _&mDetailLineNo, "　入力後"

　メソッド呼び出し　&mFormObjectName.更新モード取得( &mFormEditMode )
　トレース出力　&this, "　 ", _&mFormEditMode, "　 ", _#eof, "　入力後"

　if ( .not #eof )
　　項目値代入　 [編集フラグ] = #u
　end

手続き定義終了

手続き定義開始　prcマウスイベント初期化( )

　オブジェクト操作　&mFamilyObjectName｛ﾏｳｽｲﾝｱｳﾄ　= 0 ｝
　オブジェクト操作　&mFamilyObjectName｛ﾏｳｽ左ﾀﾞｳﾝ = 1 ｝
　&mOnMouseDownMode = 0

　オブジェクト操作　@txt内容｛入力前 = 1, 入力後 = 1 ｝

手続き定義終了

手続き定義開始　prc項目値クリア( )
　変数宣言　自動，文字列｛ &fieldName ｝
　変数宣言　自動，整数　｛ &i, &loop, &step = 1 ｝

　** 00h ～ 23h
　&loop = 23
　繰り返し　&i = 0, &loop, &step

　　&fieldName = #str( &i, 2 ) + "h"
　　トレース出力　&i, "　 ", _&fieldName

　　項目値代入　 &fieldName = #u

　繰り返し終了

手続き定義終了

引用返信 [メール受信/OFF] 削除キー/

■13849 / inTopicNo.10)

　Re[2]: クリックスライド入力

▲▼■

□投稿者/ ONnoji -(2023/07/08(Sat) 16:54:55)

時間割一覧.wfm のスクリーンショットです。

引用返信 [メール受信/OFF] 削除キー/

■13850 / inTopicNo.11)

　Re[3]: クリックスライド入力

▲▼■

□投稿者/ 尾形 -(2023/07/08(Sat) 19:50:39)

ONnojiさんありがとうございます

その通りです

時間幅はもっと狭めるのですが

しっかり勉強させていただきたいですので
まだ消さないでください

引用返信 [メール受信/OFF] 削除キー/

■13851 / inTopicNo.12)

　Re[4]: クリックスライド入力

▲▼■

□投稿者/ ONnoji -(2023/07/08(Sat) 20:21:20)

2023/07/08(Sat) 20:35:41 編集(投稿者)

> その通りです
>
> 時間幅はもっと狭めるのですが
>
> しっかり勉強させていただきたいですので
> まだ消さないでください

拙作のサンプルはまだまだ改良の余地があります。

しかし、改良にはキリがありませんので、現状のままということにします。

基本的に当方はサンプルは数日を目途に削除していますが、今回のサンプルはファイルサイズが非常に小さいのでそのまま置いておきます。

ｐ．ｓ．

時間割一覧はデータベースなのか？、と問われれば首を傾げざる負えませんね。(^^ゞ

普通、データベースという場合には、現実に対応するデータを登録したものですが、

時間割一覧は、過去・現在・将来のスケジュールが、現実に対応するデータだとは素直に認められないですね。

しかし、桐はＳＱＬ系の扱いにくいデータベースとは異なっていて、

アプリケーション開発のプラットフォーム（環境）だと思えば、これも良しなのかな～？と思い直した次第です。(^^ゞ

本当ならば、エクセルで作れば良さそうなものですが、それが桐で出来ちゃうのがスゴイところでしょうかね。アハハha。

引用返信 [メール受信/OFF] 削除キー/

■13895 / inTopicNo.13)

　Re[5]: クリックスライド入力

▲▼■

□投稿者/ 尾形 -(2023/08/08(Tue) 14:27:09)

ONnojiさん

すいません

もし可能であれば
再度、前回のサンプルを
DLさせていただきたいのですが

間違って、色々といじってしまって
原本が再度欲しくなってしまいまして。。。
今度は原本確保しておきますので

よろしくお願いします

引用返信 [メール受信/OFF] 削除キー/

■13896 / inTopicNo.14)

　Re[6]: クリックスライド入力

▲▼■

□投稿者/ ONnoji -(2023/08/08(Tue) 18:33:36)

> 再度、前回のサンプルをDLさせていただきたいのですが

貴殿のご要望には添いかねますので、あしからずご了承ください。

当方が添付ファイルを削除するのは以下の理由によります。

・あくまでも参考であって問題を解決するものではありません

・サンプルは当方の著作権が適用されるので、ネット上に放置するのは好ましくないと考えています

ということで、最近ではフォーム・イベント処理・表の定義情報をテキスト情報として投稿して、
　　　　　　　・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・
添付ファイル自体は削除するようにしています。
・・・・・・・・・・・・・

なお、添付ファイルは【多遊】さんのサイトの負担にもなりますのでご理解ください。

というわけで、

　■13848 / 1階層)　Re[1]: クリックスライド入力
　□投稿者/ ONnoji -(2023/07/08(Sat) 16:48:18)

のフォーム・イベント処理・表の定義情報を参考にしてください。

また、同投稿のフォーム定義情報の＜2023.08.08　追記＞もお読みください。

ｐ．ｓ．

あのサンプルは即席で作ったのものなので正直言って気に入っていません。

大事なのは、マウスドラッグの考え方だけだと思いますよ。

ドラッグするテキストオブジェクト（txt00 ～ txt23）は、ﾌｫｰｶｽの設定 = 禁止に設定されています。

これはマウス左ダウンした際にテキストオブジェクトのエディタに進入しないようにするためですが、
これは苦肉の策かもしれません。
ﾌｫｰｶｽの設定 = 禁止にせずとも、マウス右のイベントにすれば、テキストオブジェクトのエディタに進入しないような・・・

いずれにしても、当方がお伝えしたかったのは［マウスドラッグの考え方］だけということです。

余談ですが、現在当方はガントチャートのフォームを研究しています。
これは予見していたことではありますが、明細部のオブジェクトを対象にドラッグするのはとても面倒なことだと再確認しました。
そこで、マウス左ボタンでドラッグするよりも、マウス右ボタンでドラッグする方が適しているような気がしています。

引用返信 [メール受信/OFF] 削除キー/

■13897 / inTopicNo.15)

　Re[7]: クリックスライド入力

▲▼■

□投稿者/ 尾形 -(2023/08/09(Wed) 04:17:03)

ONnojiさん

お返事ありがとうございました

なんとか、頑張ってみます

引用返信 [メール受信/OFF] 削除キー/

■13934 / inTopicNo.16)

　Re[7]: クリックスライド入力

▲▼■

□投稿者/ 尾形 -(2023/09/02(Sat) 07:55:36)

ONnojiさん

色々とありがとうございました
とても参考になりました

&属性 = "#条件選択(&カーソル行=#行番号 .and #終端行<>1,""背景色'朱色'"")"
オブジェクト操作　&OBJ.編集属性式 = &属性

背景色を直接操作するのではなく
編集属性式を操作する事で
自分的には納得できる操作性ができました

ありがとうございました

引用返信 [メール受信/OFF] 削除キー/

このトピックをツリーで一括表示

トピック内ページ移動 / << 0 >>

このトピックに書きこむ

入力内容にタグは利用できません。

他人を中傷する記事は管理者の判断で予告無く削除されます。
半角カナは使用しないでください。文字化けの原因になります。
名前、コメントは必須記入項目です。記入漏れはエラーになります。
入力内容の一部は、次回投稿時の手間を省くためブラウザに記録されます。
削除キーを覚えておくと、自分の記事の編集・削除ができます。
URLは自動的にリンクされます。
記事中に No*** のように書くとその記事にリンクされます(No は半角英字/*** は半角数字)。
- No123 → 記事No123の記事リンクになります(指定表示)。
- No123,130,134 → 記事No123/130/134 の記事リンクになります(複数表示)。
- No123-130 → 記事No123～130 の記事リンクになります(連続表示)。

■お願い－－－－－－－

質問には、できるだけ「OS・桐 Ver」等ご記入願います
将来ここに掲載されました内容を、桐のファイルへ変換予定です。
できましたら、3,500文字以内位での投稿お願い致します

■ご注意(Comment)－－－－－

通常モード・・・通常文章等
図表モード・・・等幅表示(イベントや数字等を記入したとき：初期設定)

■解決しましたら最下段にチェックを入れてください

■引用文は、最小限に、お願いいたします

Name	/
E-Mail	/
└> 関連するレス記事をメールで受信しますか? / アドレス
Title	/
メッセージ中には下記URLと同じURLを書き込まないで下さい
URL	/
Comment/ 通常モード->　図表モード-> (適当に改行して下さい/半角10000文字以内) ■No13934に返信(尾形さんの記事) > ONnojiさん > > 色々とありがとうございました > とても参考になりました > > > &属性 = "#条件選択(&カーソル行=#行番号 .and #終端行<>1,""背景色'朱色'"")" > オブジェクト操作　&OBJ.編集属性式 = &属性 > > 背景色を直接操作するのではなく > 編集属性式を操作する事で > 自分的には納得できる操作性ができました > > > ありがとうございました > >
File	/ アップ可能拡張子=> /.gif/.jpg/.jpeg/.png/.txt/.lzh/.zip/.mid 圧縮ファイル[lzh,zip]は、事前に解凍してご利用下さい。 1) 太字の拡張子は画像として認識されます。 2) 画像は初期状態で縮小サイズ250×250ピクセル以下で表示されます。 3) 同名ファイルがある、またはファイル名が不適切な場合、　　ファイル名が自動変更されます。 4) アップ可能ファイルサイズは1回100KB(1KB=1024Bytes)までです。 5) ファイルアップ時はプレビューは利用できません。 6) スレッド内の合計ファイルサイズ:[0/500KB] 残り:[500KB]
パスワード	/ 半角小文字で「ケイ・アイ・アール・アイ」を入力
削除キー	/ (半角8文字以内)
解決済み! BOX/ 解決したらチェックしてください!
プレビュー/

- Child Tree -
- Antispam Version -