E-Mail

E-Mail

>folder.htt で、「サム寝入る表示＆クリックでファイル名をクリップボードに＆
>フォルダを閉じる」を作れば、桐から呼び出せば使えそうですね。

ハイ！私もそれを考えていました。
（これは後で出てくるセキュリティ問題を回避するためにも有効かも？）

あとはですね？次のような VBS をデスクトップ上に置いておき，
そに対しエクスプローラからドラッグ＆ドロップする(させる)方法
もあると思います。これですとフォルダのカスタマイズは必要あり
ません。ドラッグドロップしたファイルが存在すれば，元のウィン
ドウも閉じられるはずです。
複数ファイルのドラッグドロップも可能ですが，あとは桐側の受け
入れ方法の問題です。

桐で場所を指定してエクスプローラを開くのは簡単ですし，後は
explorer.exe のタスク確認と，クリップボードデータの更新確認
をチェックすれば良いでしょうか？

-----------------------------------------------------------------------
Option Explicit
Dim Arg, WS, FS, SH, Args, n, File, Name, Path, TrueName, Ret
Set Arg = WScript.Arguments
Set WS  = WScript.CreateObject("WScript.Shell")
Set FS  = WScript.CreateObject("Scripting.FileSystemObject")
If Arg.Count > 0 Then
  For Each n in Arg
    Args = Args & n & vbCrLf
  Next
  File = Arg(0)
  If FS.FileExists(File) Then
    Name = FS.GetFileName(File)
    Path = FS.GetParentFolderName(File)
    Set Arg = Nothing
  Else
    Ret = WS.Popup( "ファイルがありません！" _
                   , 3 _
                   , "確認" _
                   , 0)
    Set FS  = Nothing
    Set WS  = Nothing
    Set Arg = Nothing
    WScript.Quit
  End If
Else
  Ret = WS.Popup( "オプションを指定して下さい！" _
                 , 3 _
                 , "確認" _
                 , 0)
  Set FS  = Nothing
  Set WS  = Nothing
  Set Arg = Nothing
  WScript.Quit
End If

Dim IE
Set IE = WScript.CreateObject("InternetExplorer.Application")
IE.Navigate "about:blank"
Do While IE.ReadyState<>4
  WScript.Sleep 100
Loop
IE.Document.ParentWindow.ClipboardData.SetData "Text", Args
IE.Quit
Set IE = Nothing

Dim Process
For Each Process in GetObject("winmgmts:{impersonationLevel=impersonate}").ExecQuery("SELECT * FROM Win32_Process WHERE NAME='explorer.exe'")
  WS.AppActivate Path
  WS.Sendkeys("%{F4}")
Next

Set FS = Nothing
Set WS = Nothing
-----------------------------------------------------------------------

上記スクリプトは IE を使ってクリップボードにファイル名を
コピーしています。ですので，IE が入っていてデフォルトの
状態であれば使えるはずです。

但し，この IE の状態はセキュリティ上好ましい状態とは言え
ません。でも，MS は仕様だと言い張り改善する見込みはあり
ません。設定には十分注意して下さい。

このクリップボードの使用が可能かどうかは「インターネット
のプロパティ」の「セキュリティ」の設定によります。
スクリプトによる貼り付けを許可してあれば使えます。
でも，これを許可しているとインターネットを徘徊している間
に知らぬうちに，自分のクリップボードの内容を収集されている
場合もあるかも？知れません。
（大切なものを盗まれませんように！）

あと，最後のエクスプローラウィンドウを閉じるところはもう
少し工夫した方が良いかも知れません。
エクスプローラからでないドラッグ＆ドロップの場合にカレント
ウィンドウが間違って閉じられる場合があるかも知れません。

E-Mail