>自動実行プログラムに，自分で書いた setup.vbs
>を指定してしまうと言うのもあると思います。

一応サンプル的に作ってみました！　<setup.vbs>

一番簡単なものとして，一式は LZH で圧縮して
配布するものとして，解凍先などは自己解凍型の
実行ファイルに任せてしまうものとします。

そして，その配布ファイルの中に次のような
setup.vbs も一緒に含ませておき，解凍時に自動
実行するように仕込んでおきます。実行時の指定は

setup.vbs 桐で開くファイル名 ショートカットの名前
（ setup.vbs メニュー.wfm 桐のサンプル )

とします。
これで，デスクトップ上にサンプルを実行する
ショートカットが作成されるはずです。

setup.vbs は，桐のバージョンも自動判定し，
インストールフォルダも自動取得します。
(但し Ver8 と Ver 9 のみ)
また，開くファイルは，解凍する時に指定した
フォルダ( setup.vbs を起動したフォルダ)を
カーレントフォルダとして，そこにあるファ
イルのショートカット作成します。

setup.vbs
'-------------------------------------------------------------------------------
Option Explicit
Dim Arg, WS, FS, SH, NS, File, Name, Path, TrueName, Ret
Dim KiriVer, KiriPath, KiriExe, KiriArg, KiriTitle, Desktop, Link
Set Arg = WScript.Arguments
Set WS  = WScript.CreateObject("WScript.Shell")
Set FS  = WScript.CreateObject("Scripting.FileSystemObject")
Set SH  = WScript.CreateObject("Shell.Application")
If Arg.Count = 2 Then
  File = Arg(0)
  KiriTitle = Arg(1)
  If FS.FileExists(File) Then
    Name = FS.GetFileName(File)
    Path = FS.GetParentFolderName(File)
    If IsNull(Path) Or Path = "" Then Path = FS.GetAbsolutePathName(".\")
    Set NS = SH.NameSpace(Path)
    TrueName = NS.ParseName(Name)
    Name = FS.GetAbsolutePathName(TrueName)
    Set NS  = Nothing
    Set SH  = Nothing
    Set FS  = Nothing
    Set Arg = Nothing
  Else
    Ret = WS.Popup( "ファイルがありません！" _
                   , 3 _
                   , "確認" _
                   , 0)
    Set SH  = Nothing
    Set FS  = Nothing
    Set WS  = Nothing
    Set Arg = Nothing
    WScript.Quit
  End If
Else
  Ret = WS.Popup( "オプションを指定して下さい！" _
                 , 3 _
                 , "確認" _
                 , 0)
  Set SH  = Nothing
  Set FS  = Nothing
  Set WS  = Nothing
  Set Arg = Nothing
  WScript.Quit
End If

KiriVer = WS.RegRead("HKCR\.tbl\")
If     KiriVer = "Kiri8tbl" Then
  KiriPath = WS.RegRead("HKLM\SOFTWARE\K3\KIRI\8.0\Path")
  KiriExe = KiriPath & "\System\kiri8.exe"
ElseIf KiriVer = "Kiri9tbl" Then
  KiriPath = WS.RegRead("HKLM\SOFTWARE\K3\KIRI\9.0\Path")
  KiriExe = KiriPath & "\System\kiri9.exe"
Else
  Ret = WS.Popup( "桐の関連付けがありません！" _
                , 0 _
                , "桐の関連付け確認" _
                , 0)
  Set WS  = Nothing
  WScript.Quit
End If

If Right(Path,1) = "\" Then Path = Path & "\" '桐のバグ対策
KiriPath = KiriPath & "\System"
KiriArg = "-DP " &  _
          """" & _
          Path & _
          """" & _
          " -O " & _
          """" & _
          Name & _
          """"

Desktop = WS.SpecialFolders("Desktop")
Set Link = WS.CreateShortcut(Desktop & "\" & KiriTitle & ".lnk")
Link.TargetPath = KiriExe
Link.Arguments = KiriArg
Link.WindowStyle = 1
Link.Hotkey = "CTRL+SHIFT+K"
Link.IconLocation = KiriExe & ", 0"
Link.Description = KiriTitle
Link.WorkingDirectory = KiriPath
Link.Save

Set Link = Nothing
Set Desktop = Nothing
Set WS = Nothing
WScript.Quit
'-------------------------------------------------------------------------------

E-Mail

E-Mail

１）桐の環境設定に、登録？することはできないでしょうか

役に立つかどうかわかりませんが，随分前に作った KIRI8.INI を
書き換える VBS です。この時は Expand Ctrl Char の設定変更で
した。正規表現までは使っていないタイプですね！　桐9 だと環境
設定ファイル名も場所も変わってきます。

Dim WS, FS
Set WS = WScript.CreateObject("WScript.Shell")
Set FS = WScript.CreateObject("Scripting.FileSystemObject")

Dim KiriPath, KiriIni, KiriChk, file1, file2
KiriPath = WS.RegRead("HKLM\SOFTWARE\K3\KIRI\8.0\Path")
KiriIni = KiriPath + "\System\kiri8.ini"
KiriChk = KiriPath + "\System\kiri8.chk"
If FS.FileExists(KiriChk)=True Then
    FS.DeleteFile KiriChk,True
End If
Set file1 = FS.OpenTextFile(KiriIni)

Dim IniStr
Do Until file1.AtEndOfStream
    IniStr = file1.ReadLine
    If IniStr = Chr(&h1A) Then
        Exit Do
    ElseIf InStr(IniStr,"Expand Ctrl Char") Then
        IniStr = Right(IniStr,1)
        If IniStr = "1" Then
            Set file2 = FS.CreateTextFile(KiriChk)
            file2.WriteLine("Expand Ctrl Char=1")
            file2.Close
        End If
        Exit Do
    End If
Loop 

file1.Close
Set FS = Nothing
Set WS = Nothing
WScript.Quit


>私の場合、デスクトップにいくつか桐のフォームをショートカットで
>おいてます。このような感じができれば、なおいいのですが。
>(バッチファイル？でもいいのですが、よく解りません)

WSH (VBScriptやJScript) を使えばリンク(ショートカット)を作る
事も可能です。サンプル的には下記に出ていますが，WSH 直接では
無く，桐からショートカットを作るための WSH を書き出している
サンプルになっています。

http://www2u.biglobe.ne.jp/~s_tanaka/cgi-bin/bbs/bbs.cgi?function=logview_html&no=20#992
http://www2u.biglobe.ne.jp/~s_tanaka/cgi-bin/bbs/bbs.cgi?function=logview_html&no=20#997

E-Mail

ちょうど @IT に Excel で「ファイルの一覧情報リストを取得する」
http://www.atmarkit.co.jp/fwin2k/win2ktips/310filelist/filelist.html
と言うのがありましたが，これに下記のような Function を書いて，
FileDisp(strPath, i) に shtFile.Cells(i, 9) = GetKTitle(objFl)
を加えると，サブディレクトリも含めて，桐の「表題」も一緒に
一覧表リストを取得する事ができるようになりますね？　(^_^)
'-------------------------------------------------------------
Public Function GetKTitle(objFl)

  If objFl.Size < 4096 Then
    Title = ""

  ElseIf InStr(".TBL,.WFM,.FRM,.RPT,.VIW,.XVW,.CMD,.KEV", UCase(Right(objFl, 4))) = 0 Then
    Title = ""

  Else
    Dim Data(40)
    Set Stream = CreateObject("Adodb.Stream")
    Stream.Type = 1
    Stream.Mode = 3
    Stream.Open
    Stream.LoadFromFile (objFl)

  ' 対象ファイルの表題「0x34〜0x5B」を読み込む
    Stream.Position = &H34
    For i = 1 To 40
      Data(i) = Stream.Read(1)
    Next
    Stream.Close
    Set Stream = Nothing

  ' 表題を JIS から SJIS にコード変換する
    i = 0: j = 0
    For i = 1 To 40
      If (i Mod 2) = 0 Then
        c1 = AscB(Data(i))
        c2 = AscB(Data(i - 1))
        If (c1 <> 0) Then
          If (c1 Mod 2) = 1 Then
            c1 = ((c1 + 1) / 2) + &H70
            c2 = c2 + &H1F
          Else
            c1 = (c1 / 2) + &H70
            c2 = c2 + &H7D
          End If
          If (c1 >= &HA0) Then c1 = c1 + &H40
          If (c2 >= &H7F) Then c2 = c2 + 1
        ElseIf (c1 = 0 And c2 = 0) Then
          c2 = AscB(" ")
          j = j + 1
        Else
          j = j + 1
        End If
        Title = Title & Chr(c1 * &H100 + c2)
      End If
    Next
    Title = Title & Space(j)

  End If

  GetKTitle = RTrim(Title)

End Function

'-------------------------------------------------------------

>http://s3.kcn-tv.ne.jp/users/hidetake/data/ktitle.vbs

一部修正しました！
http://s3.kcn-tv.ne.jp/users/hidetake/data/ktitle.vbs

前のはファイル名にパスを含まないカーレントパスのファイル名だけを
与えたらエラーになっていたと思います。
それと，表題だけでなく BTYPE.COM の /T オプションの意味を持たす上
で，「タイムスタンプ」「ファイルサイズ」「表題」「ファイル名」を
出力するようにしました。あと，桐以外のファイルは表題が無い状態で
出力します。

例えばコマンドラインから次のように実行すれば，フォルダ内の情報を
得る事ができます。(ワイルドカードで指定しても良いでしょう！)
あるいはバッチファイルで処理しても良いです。

------------------------------------------------------------------
X:\>for %f in ("C:\K3\KIRI9\Sample\例題\フォーム\*.*") do cscript x:\ktitle.vbs "%f" >> x:\outpu.txt

X:\type outpu.txt
2002/09/18 09:02:00      69,813 第１章　フォーム操作の練習用             0フォーム操作の練習.WFM
2002/09/18 09:02:00      38,365 第１章　フォーム操作の練習2　電話番号    0フォーム操作の練習2.WFM
2002/09/18 09:02:00      63,157 第４章　売上げ伝票の作成例               1売上げ伝票作成例.WFM
2002/09/18 09:02:00     139,264 個人住所録                               JUSHO.TBL
2002/09/18 09:02:00      79,186 第２、３章　jusho練習の作成例            JUSHO.WFM
2002/09/18 09:02:00     163,840 生徒別成績管理マスター 編集属性付き      SIKEN.TBL
2002/09/18 09:02:00     532,480 郵便番号簿：東京都のみ                   ZIPK3.TBL
2002/09/18 09:02:00      98,304 サブフォーム用                           サブ.TBL
2002/09/18 09:02:00      50,121 サブフォームの例                         サブ.WFM
2002/09/18 09:02:00     236,091 個人住所録                               テンプレート.WFM
2002/09/18 09:02:00      90,112 メインフォーム用                         メイン.TBL
2002/09/18 09:02:00      35,267 メインフォームの例                       メイン.WFM
2002/09/18 09:02:00      17,336 メニューの例                             メニュー.WFM
2002/09/18 09:02:00      98,304 商品マスター                             商品.TBL
2002/09/18 09:02:00      27,437 商品マスター入力用                       商品.WFM
2002/09/18 09:02:00      81,920 第４章　売上げ伝票入力用                 売上げ伝票.TBL
2002/09/18 09:02:00      81,920 第４章　売上げ伝票の追加入力例           売上げ伝票入力後.TBL
2002/09/18 09:02:00      98,304 得意先マスター                           得意先.TBL
2002/09/18 09:02:00      36,529 得意先マスター入力用                     得意先.WFM
2002/09/18 09:02:00      42,535 カード形式作成例                         簡易作成1.WFM
2002/09/18 09:02:00      45,138 カード形式(ダイアログ）作成例            簡易作成2.WFM
2002/09/18 09:02:00      52,713 一覧表形式作成例                         簡易作成3.WFM
2002/09/18 09:02:00      59,978 伝票形式作成例                           簡易作成4.WFM
2002/09/18 09:02:00      31,215 メイン&サブ作成例                        簡易作成5.WFM
2002/09/18 09:02:00      52,724 簡易作成 一覧表の例                      試験1.WFM
2002/09/18 09:02:00      77,633 一覧表形式 グループ項目の例              試験2.WFM
------------------------------------------------------------------


蛇足？

Windows版の桐は .WFM に関して(.RPTもだけれど)は旧来の桐と大きく
ファイルの仕様が異なっています。

表題にしても，以前は２０文字しか記述できませんでしたが，.WFM に
関しては６４文字まで入力できるようになっています。
この .WFM の表題は「ウィンドウタイトル」等では６４文字表示させる
(利用する)事ができますが，「ファイルパレット」や「ファイルを開く」
ダイアログでは２０文字だけが表示可能で，あとは途中でぶち切られて
しまいます。どんなに広い画面を使用していて，表題をいくらでも表示
できる領域があっても，桐をそれを表示してはくれません。

それは，桐が Windows版になって新しく６４文字まで拡張した .WFM の
表題領域と他に，旧来の互換性のために，以前からある領域の２つに
データをダブって持っており２重管理していて，「ファイルパレット」
や「ファイルを開く」ダイアログでは，旧来の方だけを参照し利用して
いるからだと思います。今回の VBS も旧来の場所だけを参照しています。 (^^;

新しい方の表題は位置的に固定でも無いようですし，.WFM だけのもの
ですから，「ファイルパレット」や「ファイルを開く」では面倒な処理
をする手間を省くタメかも知れません。それにスピードが遅くなるのを
防ぐ？(これは現在のリソースを考えるとあまり現実的では無いか？)

それもあって，今回の VBS も，単純にできる旧来の表題領域だけを取り
出すようになっています。　(^^;


それともう１つ .WFM の表題(旧来の互換領域も)で .TBL 等と仕様が
変わっているのは，空白部分(未利用領域)のデータの埋め方が変わって
いるようです。以前は 00 20 と埋められていましたが，.WFM に関して
は 00 00 となっています。

この関係で，以前の処理で「表題」の後に単純に「ファイル名」を継ぎ
足しても「ファイル名」が表示されない現象が発生していました！ (^^;

まぁ〜，そんなこんな内容も含んだ VBS となっています。