CreateXLS.VBS
'----------------------------------------------------------------
DBPath = "L:\Book1.xls"

Set DBE = WScript.CreateObject("DAO.DBEngine.36") '97の場合は35
Set DB = DBE.Workspaces(0).OpenDatabase(DBPath, False, False, "Excel 8.0;HDR=yes;")

DB.Execute "CREATE TABLE Sheet1 (id int, data char(255));"
DB.Execute "INSERT INTO [Sheet1$] (id, data) values (111, 'ABC');"
DB.Execute "INSERT INTO [Sheet1$] (id, data) values (222, 'XYZ');"

DB.Close
Set DB = Nothing
Set DBE = Nothing
'----------------------------------------------------------------

若干のエラー処理などを入れたものです。
Text の受け渡しなどは処理によって変更するとして・・・
音量やスピードレートの変更は Text に埋め込んでも
構いませんし！

'--------------------------------------------------------------------------------
Option Explicit

Dim Text, Arg
Text = ""
For Each Arg In WScript.Arguments
  Text = Text & Arg & vbCRLF
Next
If Text = "" Then Text = "コマンドラインオプションを指定して下さい。"

Dim Fs, File
Set Fs = CreateObject("Scripting.FileSystemObject")
File = "KillVoice.txt"  ' 中断処理のためのフラグファイルを指定

Dim Speech, Talker
On Error Resume Next
Set Speech = CreateObject("SAPI.SpVoice")
If Err then Err.Clear:Msgbox "SAPIがインストールされていません!!!":WScript.Quit

Talker = "LH Naoko"    ' Talker = Microsoft Sam / LH Kenji / LH Naoko
If Speech.GetVoices.Count > 0 Then
  Dim i
  For i = 0 To Speech.GetVoices().Count
    If Speech.GetVoices.Item(i).GetDescription = Talker Then
      Set Speech.Voice = Speech.GetVoices.Item(i)
      Exit For
    End If
  Next
Else
  Msgbox "このパソコンには音声合成ファイルがインストールされていません!!!"
  WScript.Quit
End If

If Speech.Voice.GetDescription <> Talker Then
    Msgbox "このパソコンには指定された日本語の話せる " & _
           vbCRLF & _
           Talker & _
           " さんがインストールされていません!!!"
    WScript.Quit
End If

Speech.Rate   =   0 ' -10 〜 +10
Speech.Volume = 100 ' 0 〜 100
Speech.Speak Text, 3

Do
  If Fs.FileExists(File) Then
    Speech.Speak "", 2
    Fs.DeleteFile File, True
  End If
Loop Until Speech.WaitUntilDone(10)

WScript.Quit

' Enum SpeechVoiceSpeakFlags
'    'SpVoice flags
'     SVSFDefault          =    0
'     SVSFlagsAsync        =    1
'     SVSFPurgeBeforeSpeak =    2
'     SVSFIsFilename       =    4
'     SVSFIsXML            =    8
'     SVSFIsNotXML         =   16
'     SVSFPersistXML       =   32
' 
'    'Normalizer flags
'     SVSFNLPSpeakPunc     =   64
' 
'    'Masks
'     SVSFNLPMask          =   64
'     SVSFVoiceMask        =  127
'     SVSFUnusedFlags      = -128
' End Enum
'--------------------------------------------------------------------------------

KillVoice.txt が存在したら読み上げを中止するスクリプト！
途中で KillVoice.txt が作成されても中断します。
中断したら KillVoice.txt は削除します。

-----------------------------------------------------
Set Fs = CreateObject("Scripting.FileSystemObject")
File="KillVoice.txt"
Text = _
"クリップボードのテキストを読み上げる VBScript" & _
"クリップボードの操作には前に書いたともうけれど" & _
"AutoItX を使っています。" & _
"クリップボードに適当なテキストをコピーした上で" & _
"実行して下さい。"

Set Speech = CreateObject("SAPI.SpVoice")
Set Speech.Voice = Speech.GetVoices().Item(1)
Set Status = Speech.Status

Speech.Rate =     0 ' -10 〜 +10
Speech.Volume = 100 ' 0 〜 100
Speech.Speak Text,3

Do
  If Fs.FileExists(File) Then
    Speech.Speak "",2
    Fs.DeleteFile File
  End If
Loop Until Speech.WaitUntilDone(10)
WScript.Quit
-----------------------------------------------------

折角だから・・・

クリップボードのテキストを読み上げる VBScript
クリップボードの操作には前に書いたともうけれど
AutoItX を使っています。
クリップボードに適当なテキストをコピーした上で
実行して下さい。

-----------------------------------------------------
Set oAutoIt = CreateObject("AutoItX.Control")
Text = oAutoIt.ClipGet
Set Speech = CreateObject("SAPI.SpVoice")
Set Speech.Voice = Speech.GetVoices().Item(1)
Speech.Rate = -10 ' -10 〜 +10
Speech.Volume = 100 ' 0 〜 100
Speech.Speak Text
-----------------------------------------------------


次にテキストファイルを読み上げるスクリプト。
コマンドラインで起動オプションとしてファイル名を
指定しても良いし、ドラッグドロップでテキスト
ファイルをドロップしても良いです。

-----------------------------------------------------
Set arg = WScript.Arguments
If Arg.Count < 1 Then
    WScript.Quit
End If

Set fs = CreateObject("Scripting.FileSystemObject")
Set txt = fs.OpenTextFile(arg(0))

Text = txt.ReadAll
txt.Close

Set Speech = CreateObject("SAPI.SpVoice")
Set Speech.Voice = Speech.GetVoices().Item(1)
Speech.Rate = -10 ' -10 〜 +10
Speech.Volume = 100 ' 0 〜 100
Speech.Speak Text
-----------------------------------------------------

細かいエラー処理などは省略してあります。後は作り方
さえだけで、結構遊べると・・・

SpeechXP.VBS (一部改変)
-------------------------------------------------------------------
' SpeechXP.VBS V1.02 (C) yoshioka.teruo@nifty.com 2005-05-28
' SpeechXP.VBS speeches text with SAPI.
' Usage: SpeechXP.VBS text

Option Explicit
Dim Text
Dim arg

Text=""
For Each arg In WScript.Arguments
  Text=Text & arg & vbCRLF
Next

If Not Text="" Then CreateObject("SAPI.SpVoice").Speak Text
-------------------------------------------------------------------

Option Explicit
Dim Text, Speech, Voice
Text="こんにちは"
Set Speech = CreateObject("SAPI.SpVoice")
Set Speech.Voice = Speech.GetVoices().Item(1)
Speech.Rate   = -10 ' -10 〜 +10
Speech.Volume = 100 ' 0 〜 100
Speech.Speak Text