HOME HELP 新規作成 新着記事 ツリー表示 スレッド表示 トピック表示 ファイル一覧 検索 過去ログ

ツリー一括表示

Nomal ONnojiさんへのご相談 /なか (22/09/19(Mon) 09:59) #13569
Nomal Re[1]: ONnojiさんへのご相談 /ONnoji (22/09/19(Mon) 10:56) #13570
  └Nomal Re[2]: ONnojiさんへのご相談 /なか (22/09/19(Mon) 12:39) #13571
    └Nomal Re[3]: ONnojiさんへのご相談 /ONnoji (22/09/19(Mon) 13:03) #13572
      └Nomal Re[4]: ONnojiさんへのご相談 /なか (22/09/19(Mon) 14:13) #13573
        └Nomal Re[5]: ONnojiさんへのご相談 /なか (22/09/19(Mon) 18:41) #13574 解決済み!


親記事 / ▼[ 13570 ]
■13569 / 親階層)  ONnojiさんへのご相談
□投稿者/ なか -(2022/09/19(Mon) 09:59:50)
    ONnojiさんへのご相談

    以前、↓で大変お世話になった「なか」と申します。
    https://tayu.o0o0.jp/bbs/kiri/cbbs.cgi?mode=one&namber=13503&type=0&space=0&no=0

    その際、いただいたファイルはテスト完了済みですが、肝心の改行前の本体データが完成しておらず。今月中には完成させ、いただいたファイルで改行編集の最終形を完成させられればと考えています。

    それとは別にもう一つご協力いただけないか、ご相談させていただきたいことがあります。以前作成いただいたファイルの別バージョンをお作りいただけないでしょうか。私のスキルでは到底できず、ご厚意に甘えさせていただけないかご相談する次第です。

    ■条件(前回と全く同じ内容)
    ・各文章の先頭に、1から始まり順番に番号がふられています。
    ・先頭番号と文章の間には半角スペースがあります。
    ・各文章の文字数は様々です。
    ・各文章は40文字程度で改行されます。但し、必ず40文字ではなく、おおよそ40文字での改行です。
    ・先頭番号が変わると同時に改行される場合もありますが、次の先頭番号が半角スペースを挟んで文中から始まる場合もあり、様々です。
    ・文字数が40文字程度以下の為、改行されない文章もあります。
    ・先頭番号は1から始まり、ある程度番号を重ねるとリセットされ、リセットされると次の文章番号が1になります。
    ・1〜3でリセットされる場合もあれば、1〜99でリセットさせる場合もあり、様々です。ごくわずかですが、1〜150などの3桁までの番号がつく文章もあります。
    ・各文章は、"、" "。" "」"で終わる場合やひらがなで終わる場合もあり、様々です。

    ■条件(上記条件に新規追加する条件)
    ・文字は全て半角英数(日本語なし)
    ・改行をなくして、行を統合する際、半角スペースを1つ入れて統合したい。
    理由:英語の文書であるため、改行をなくして行を統合する際、統合部分の単語がスペースなしの1単語に統合されてしまう

    ■例は以下の通りです。

    編集前:
    1 Abc def ghi jkl mno pqr stu vwx zy.
    2 Abc def ghi jkl mno
    pqr stu vwx zy.
    3 Abc def ghi
    jkl mno pqr
    stu vwx zy.
    4 Abc, def, ghi, jkl, mno, pqr, stu, vwx, zy.
    5 Abc, def, ghi, jkl, mno,
    pqr, stu, vwx, zy.
    6 Abc, def, ghi,
    jkl, mno, pqr,
    stu, vwx, zy.
    7 Xyz uvw rst opq lmn ijk fgh cde ab.
    8 Xyz uvw rst opq
    lmn ijk fgh cde ab.
    9 Xyz uvw rst opq
    lmn ijk fgh
    cde ab.

    編集後:
    1 Abc def ghi jkl mno pqr stu vwx zy.
    2 Abc def ghi jkl mno pqr stu vwx zy.
    3 Abc def ghi jkl mno pqr stu vwx zy.
    4 Abc, def, ghi, jkl, mno, pqr, stu, vwx, zy.
    5 Abc, def, ghi, jkl, mno, pqr, stu, vwx, zy.
    6 Abc, def, ghi, jkl, mno, pqr, stu, vwx, zy.
    7 Xyz uvw rst opq lmn ijk fgh cde ab.
    8 Xyz uvw rst opq lmn ijk fgh cde ab.
    9 Xyz uvw rst opq lmn ijk fgh cde ab.

    ご協力いただくことは可能でしょうか。ご検討よろしくお願いします。
[ □ Tree ] 返信 [メール受信/OFF] 削除キー/

▲[ 13569 ] / ▼[ 13571 ]
■13570 / 1階層)  Re[1]: ONnojiさんへのご相談
□投稿者/ ONnoji -(2022/09/19(Mon) 10:56:24)
    > ご協力いただくことは可能でしょうか。ご検討よろしくお願いします。

    OKですよ。(*^^)Ok

    現在台風が接近中なのでPC作業の時間が十分ありません。

    ご返事は9/21以降になります。

    ご了承ください。

[ 親 13569 / □ Tree ] 返信 [メール受信/OFF] 削除キー/

▲[ 13570 ] / ▼[ 13572 ]
■13571 / 2階層)  Re[2]: ONnojiさんへのご相談
□投稿者/ なか -(2022/09/19(Mon) 12:39:15)
    お助けいただきありがとうございます。

    決して急ぎませんので、お時間のある際によろしくお願いします。

    ご厚意に感謝します。
[ 親 13569 / □ Tree ] 返信 [メール受信/OFF] 削除キー/

▲[ 13571 ] / ▼[ 13573 ]
■13572 / 3階層)  Re[3]: ONnojiさんへのご相談
□投稿者/ ONnoji -(2022/09/19(Mon) 13:03:25)
    2022/09/21(Wed) 22:52:59 編集(投稿者)
    2022/09/19(Mon) 13:04:09 編集(投稿者)

    > ご返事は9/21以降になります。

    あまりにも簡単な変更でしたので完成しました。

    添付ファイルをアップします。

    改行の修正_英文対応版.kex
    改行の修正_英文対応版.tbx
    改行の修正_英文対応版.wfx

    ダウンロードしてご確認ください。

    なお、現在台風から避難する関係で当方のPC作業の時間が無くなります。

    次にご返事できるのは9/21以降になります。

    添付ファイルは数日を目途に削除しますので、お早めにダウンロードしてください。


    p.s.

    ■改行の修正_英文対応版.kex

    名札  メイン



    手続き定義開始 cmd英文テキストデータ出力Click( )
     変数宣言 自動,文字列{ &icon, &title = "cmd英文テキストデータ出力Click( )", &msg }
     変数宣言 自動,文字列{ &string }
     変数宣言 自動,文字列{ &text }
     変数宣言 自動,文字列{ &chr }
     変数宣言 自動,文字列{ &numList = "1,2,3,4,5,6,7,8,9,0" }
     変数宣言 自動,文字列{ &indexChr }
     変数宣言 自動,文字列{ &SP = #jis( #hex("20") ) }
     変数宣言 自動,整数 { &traceON }
     変数宣言 自動,整数 { &multiTblNum }
     変数宣言 自動,整数 { &length }
     変数宣言 自動,整数 { &pos, &cnt, &offset }
     変数宣言 自動,整数 { &i, &loop, &step = 1 }

     変数宣言 自動,文字列{ &outputTxtName = #一括パス名 + "test_English.txt" }
     変数宣言 自動,整数 { &status印字開始 }
     変数宣言 自動,整数 { &ans }
     変数宣言 自動,長整数{ &longError }

     &traceON = 0
     条件 ( &traceON ) トレース出力 &title + "を実行開始しました"

     編集表 &hwindow
     多重化
     &multiTblNum = #is表
    ┌if ( &multiTblNum )

    │ *----- begin テキストファイル作成 -----*
    │ 印字終了
    │ 印字開始 &outputTxtName, 終了状態 = &status印字開始

    │ ジャンプ 行番号 = 先頭
    │┌繰り返し ( .not #eof )
    ││
    ││ &text  = [テキスト]
    ││┌if ( #対応番号( &numList, #sstr( &text, 1, 1 ) ) = 0 )
    │││ &text = &SP + #trim( &text, 1 )
    ││└end
    ││ &length = #文字数( &text )
    ││ 条件 ( &traceON ) トレース出力 _&text, "  ", _&length
    ││
    ││ &loop = &length
    ││┌繰り返し &i = 1, &loop, &step
    │││
    │││ &chr = #sstr( &text, &i, 1 )
    │││
    │││┌if ( #対応番号( &numList, &chr ) <> 0 )
    ││││
    ││││ &offset = 0
    ││││ &pos  = &i
    ││││┌繰り返し &cnt = 1, 5, &step /* 1 〜 999999 までのインデックスに対応 */
    │││││
    │││││ &offset = &cnt
    │││││ &indexChr = #sstr( &text, &pos + &cnt, 1 )
    │││││┌if ( #対応番号( &numList, &indexChr ) = 0 )
    ││││││ &offset = &cnt - 1
    ││││←┼─繰り返し中止
    │││││└end
    ││││└繰り返し終了
    ││││
    ││││ 条件 ( &traceON ) トレース出力 _&string, " , _13, _10,"
    ││││ 条件 ( &status印字開始 = 1 .and &string <> #u ) 印字 &string, _13, _10,
    ││││ &string = #sstr( &text, &i, 1 + &offset )
    ││││ &i = &i + &offset
    ││││
    │││├else
    ││││
    ││││ &string = &string + &chr
    │││└end
    │││
    ││└繰り返し終了
    ││
    ││ ジャンプ 行番号 = 次行
    │└繰り返し終了
    │ 条件 ( &traceON ) トレース出力 _&string, " , _13, _10,"
    │ 条件 ( &status印字開始 = 1 ) 印字 &string, _13, _10,

    │ 終了 表 &multiTblNum
    └end
     編集表 &hwindow

    ┌if ( &status印字開始 = 1 )

    │ 印字終了
    │ &msg =     "テキストファイルを出力しました"
    │ &msg = &msg + "\n\n&outputTxtName = " + #文字置換( &outputTxtName, "\", "\\" )
    │ &msg = &msg + "\n\nファイルを見ますか?"
    │ メッセージボックス &title, &msg, アイコン = i, ボタン指定 = 5, 制御文字展開 = する, &ans
    │┌if ( &ans = 6 )
    ││ シェル実行 &outputTxtName, &longError
    │└end
    ├else

    │ &msg =     "コマンドの実行に失敗しました"
    │ &msg = &msg + "\n\n印字開始 &outputTxtName, 終了状態 = &status印字開始"
    │ &msg = &msg + "\n\n&outputTxtName = " + #文字置換( &outputTxtName, "\", "\\" )
    │ &msg = &msg + "\n\n&status = " + #str( &status印字開始 )
    │ メッセージボックス &title, &msg, アイコン = e, ボタン指定 = 1, 制御文字展開 = する, &ans
    └end

     &msg =     "done"
     **メッセージボックス &title, &msg, アイコン = i, ボタン指定 = 1, 制御文字展開 = する

     条件 ( &traceON ) トレース出力 &title + "を実行終了しました"
    手続き定義終了


[ 親 13569 / □ Tree ] 返信 [メール受信/OFF] 削除キー/

▲[ 13572 ] / ▼[ 13574 ]
■13573 / 4階層)  Re[4]: ONnojiさんへのご相談
□投稿者/ なか -(2022/09/19(Mon) 14:13:29)
    早速ありがとうございます。ご厚意に感謝します。

    ダウンロードさせていただきました。

    確認の上、再度ご連絡させていただきます。
[ 親 13569 / □ Tree ] 返信 [メール受信/OFF] 削除キー/

▲[ 13573 ] / 返信無し
■13574 / 5階層)  Re[5]: ONnojiさんへのご相談
□投稿者/ なか -(2022/09/19(Mon) 18:41:39)
    2022/09/19(Mon) 18:42:59 編集(投稿者)

    確認させていただきました。
    実現したいことが完璧にできました。

    今回も助けていただき大変ありがとうございました。
    ご支援に心から感謝しております。
解決済み!
[ 親 13569 / □ Tree ] 返信 [メール受信/OFF] 削除キー/


Mode/  Pass/

HOME HELP 新規作成 新着記事 ツリー表示 スレッド表示 トピック表示 ファイル一覧 検索 過去ログ

- Child Tree -
- Antispam Version -