| 以下の行を一括処理エディターにコピーして作成してはいかがでしょうか。
変数宣言 固有, 整数 { &Itb2 , &Itb1 , &I終了1 , &I終了2 , &I終了3 , &I終了4 }
変数宣言 共通, 数値 { &選択番号 = 0 , &最大連番 }
変数宣言 共通, 文字列 {&支店名,&fn}
表 "book2.tbl", リトライ=しない, 終了状態=&I終了1
ケース開始
ケース (&I終了1<>1)
手続き実行 メッセージ表示( "開く",&I終了1 )
ケース (&I終了1=1)
代入 &Itb1 = #IS表
解除 *
絞り込み 単一化={[F2]}
書き出し 表, "作業表.tbl",, 終了状態 = &I終了3, {[F2]}
if (&I終了3 <> 1)
手続き実行 メッセージ表示( "書き出し",&I終了3 )
else
解除 *
表 "作業表.tbl", リトライ=しない, 終了状態=&I終了2
if (&I終了2 <> 1)
手続き実行 メッセージ表示( "開く",&I終了2 )
else
代入 &Itb2 = #IS表
繰り返し ( .not #eof )
代入 &選択番号 = &選択番号+1 , &支店名 = [F2]
編集表 &Itb1
絞り込み [F2]{ &支店名}, 文字比較方法=自動, 部分一致検索=しない
if (&選択件数<>0)
書き出し CSV, #STR(&選択番号,3)+&支店名+".csv",, 項目名=する, 終了状態 = &I終了4,{[F1],[F2]}
end
絞り込み解除 1
編集表 &Itb2
ジャンプ 行番号 = 次行
繰り返し終了
終了 表 &Itb2
終了 表 &Itb1
end
end
ケース終了
終了
手続き定義開始 メッセージ表示(文字列 &S操作,整数 &I結果 )
変数宣言 文字列 { &Smess }
if ( &S操作 = "書き出し")
if ( &I結果 = -1 )
&Smess = "排他エラー(ファイルが既にオープン中)後刻に再実行して下さい。"
else if ( &I結果 = -2 )
&Smess = "排他エラー(ファイル排他)。後刻に再実行して下さい。"
else
&Smess = "その他のエラーです。処理を中止します。"
end
else if ( &S操作 = "開く" )
if ( &I結果 = -1 )
&Smess = "他の桐で編集中です。後刻に再実行して下さい。"
else if ( &I結果 = -2 )
&Smess = "共有情報管理ファイルが使用中で表を開けませんでした。"
else
&Smess = "その他のエラーです。処理を中止します。"
end
end
確認 &Smess
手続き定義終了
|
