(現在 過去ログ39 を表示中)

HOME HELP 新規作成 新着記事 トピック表示 ファイル一覧 検索 過去ログ

[ 最新記事及び返信フォームをトピックトップへ ]

■6057 / inTopicNo.1) 　2行について繰り返し読み込みたい
  ▼■
□投稿者/ 一太郎 -(2010/09/08(Wed) 14:21:34)
    以前、こちらで教えて頂いた一括処理ですが、追加で「読み込み.txt」の①と②を「Ｄ」と「Ｅ」に読み込んだ件数分繰り返し読み込みたい。
    よろしくお願いいたします。


    ●読み込み.TXT
    ①1111
    ②2222
    　あ
    　い
    　う


    　え
    　お
    　か


    　き
    　・
    　・

    ●変換.TBL
    「Ａ」　　「Ｂ」　　「Ｃ」　「Ｄ」　「Ｅ」
    あ　　　　い　　　　う　　　　1111　　2222
    え　　　　お　　　　か　　　　1111　　2222
    き　　　　く　　　　け　　　　1111　　2222



    ●一括処理
    変数宣言　整数,{&繰}
    変数宣言　文字列,{&文字}
    繰り返し
    　ファイル名入力　初期値="読み込み
    読み込み*.txt", プロンプト="読み込むTXTファイルを指定",&選択ファイル名
    条件(&選択ファイル名="")　繰り返し中止
    条件(&選択ファイル名="")　終了
    表　"変換"
    表　"読込.tbl"
    読み込み　テキスト,&選択ファイル名,空白削除=しない,終了状態=&実行リターン
    絞り込み 行数=14
    行削除　*
    絞り込み解除　*
    &繰=1
    繰り返し
    &文字=[データ]
    編集表　"変換"
    条件　(&繰=1)　行追加　[A]=&文字
    条件　(&繰=1)　ジャンプ　行番号=b
    条件　(&繰=2)　行訂正　[B]=&文字
    条件　(&繰=3)　行訂正　[C]=&文字

    編集表　"読込.tbl"
    ジャンプ　行番号=+1
    条件　(#終端行)　繰り返し中止
    &繰=&繰+1
    条件　(&繰=17) &繰=1
    繰り返し終了
    表　"読込.tbl"
    行削除 *
    　&置換式="済"+#ファイル名(&選択ファイル名,3)　　/*1*/
    　ファイル名変更　&選択ファイル名,&置換式　　　　/*2*/
    繰り返し終了
    終了　表　2,3

引用返信 [メール受信/OFF] 削除キー/
■6058 / inTopicNo.2) 　Re[1]: 2行について繰り返し読み込みたい
□投稿者/ eo -(2010/09/08(Wed) 18:55:22)
    １行目と２行目を変数に入れて最後までそれを使用すれば？

    変数宣言　文字列,{&A,&B,&C,&D,&E}
    表　"変換.tbl"
    行削除　*, 圧縮
    表　"読込.tbl"
    行削除　*, 圧縮
    読み込み　テキスト,"読込.txt"
    &D=[データ]
    ジャンプ　行番号=次行
    &E=[データ]
    ジャンプ　行番号=次行
    繰り返し　(.not #EOF)
    　&A=[データ]
    　ジャンプ　行番号=次行
    　&B=[データ]
    　ジャンプ　行番号=次行
    　&C=[データ]
    　編集表　"変換.tbl"
    　行追加　[A]=&A,[B]=&B,[C]=&C,[D]=&D,[E]=&E
    　編集表　"読込.tbl"
    　ジャンプ　行番号=次行
    繰り返し終了
    編集表　"変換.tbl"
    表形式編集
    表


20100908x.zip/5KB
引用返信 [メール受信/OFF] 削除キー/
■6059 / inTopicNo.3) 　Re[2]: 2行について繰り返し読み込みたい
□投稿者/ 一太郎 -(2010/09/09(Thu) 10:41:37)
    2010/09/09(Thu) 14:49:08 編集(投稿者)

    eoさんいつもありがとう御座います。

    お陰様で解決いたしました。

    テキストファイルを纏めて選択して一括処理で繰り返して読み込む方法はあるのでしょうか。
    よろしくお願いいたします。

    ●テキストファイル
    読込1.txt 読込2.txt　読込3.txt 　・・・

    ■No6058に返信(eoさんの記事)
    > １行目と２行目を変数に入れて最後までそれを使用すれば？
    >
    > 変数宣言　文字列,{&A,&B,&C,&D,&E}
    > 表　"変換.tbl"
    > 行削除　*, 圧縮
    > 表　"読込.tbl"
    > 行削除　*, 圧縮
    > 読み込み　テキスト,"読込.txt"
    > &D=[データ]
    > ジャンプ　行番号=次行
    > &E=[データ]
    > ジャンプ　行番号=次行
    > 繰り返し　(.not #EOF)
    > 　&A=[データ]
    > 　ジャンプ　行番号=次行
    > 　&B=[データ]
    > 　ジャンプ　行番号=次行
    > 　&C=[データ]
    > 　編集表　"変換.tbl"
    > 　行追加　[A]=&A,[B]=&B,[C]=&C,[D]=&D,[E]=&E
    > 　編集表　"読込.tbl"
    > 　ジャンプ　行番号=次行
    > 繰り返し終了
    > 編集表　"変換.tbl"
    > 表形式編集
    > 表
    >
解決済み!
引用返信 [メール受信/OFF] 削除キー/
■6060 / inTopicNo.4) 　Re[3]: 2行について繰り返し読み込みたい
□投稿者/ eo -(2010/09/10(Fri) 15:17:41)
    > テキストファイルを纏めて選択して一括処理で繰り返して読み込む方法はあるのでしょうか。

    txtフォルダに読み込むテキストファイルを入れて置く処理にしてます。

    変数宣言　固有,文字列{&ファイル,&ファイル名,&フォルダ,&検索ファイル,&A,&B,&C,&D,&E},数値{&ファイル数=1}
    &フォルダ=".\txt\"
    フォルダ名入力　初期値=&フォルダ,プロンプト="フォルダ選択",&フォルダ
    &ファイル="*.txt"
    &検索ファイル=&フォルダ+&ファイル
    表　"変換.tbl"
    行削除　*, 圧縮
    繰り返し
    　&ファイル名=#ファイル検索(&検索ファイル,&ファイル数)
    　　ケース開始
    　　　ケース　(&ファイル名<>"")
    　　　　表　"読込.tbl"
    　　　　行削除　*, 圧縮
    　　　　読み込み　テキスト,&ファイル名
    　　　　&D=[データ]
    　　　　ジャンプ　行番号=次行
    　　　　&E=[データ]
    　　　　ジャンプ　行番号=次行
    　　　　　繰り返し　(.not #EOF)
    　　　　　　&A=[データ]
    　　　　　　ジャンプ　行番号=次行
    　　　　　　&B=[データ]
    　　　　　　ジャンプ　行番号=次行
    　　　　　　&C=[データ]
    　　　　　　編集表　"変換.tbl"
    　　　　　　行追加　[A]=&A,[B]=&B,[C]=&C,[D]=&D,[E]=&E
    　　　　　　編集表　"読込.tbl"
    　　　　　　ジャンプ　行番号=次行
    　　　　　繰り返し終了
    　　　ケース　(&ファイル名="")
    　　　　繰り返し中止
    　　ケース終了
    　代入　&ファイル数=&ファイル数+1
    繰り返し終了
    行削除　*, 圧縮
    編集表　"変換.tbl"
    表形式編集
    表


20100910.zip/4KB
引用返信 [メール受信/OFF] 削除キー/
■6061 / inTopicNo.5) 　Re[4]: 2行について繰り返し読み込みたい
□投稿者/ 一太郎 -(2010/09/12(Sun) 11:55:07)
    eoさんありがとうございます。

    すべて思い通りになりました。
    感謝しております。
解決済み!
引用返信 [メール受信/OFF] 削除キー/


トピック内ページ移動 / << 0 >>

このトピックに書きこむ

過去ログには書き込み不可

Mode/　 Pass/

HOME HELP 新規作成 新着記事 トピック表示 ファイル一覧 検索 過去ログ

- Child Tree -
- Antispam Version -